// プロデル リバーシ //
//プロデルで作ったシンプルなリバーシ
メイン画面を表示する
待機する

メイン画面とは
	ウィンドウを継承する
	+マスサイズ=30
	+マス部品=｛｝
	+マス=｛｝
	+マス数=10
	+プレイヤ
	+黒数
	+白数
	+残り
	+ゲーム中

はじめの手順
	初期化する
	マスを初期化する
終わり

//ゲーム状態ラベル
初期化する手順
//この手順は自動生成されたものです
//編集しないでください
	この内部領域大きさは｛438，408｝
	この内容は「プロデル リバーシ」
	このドラッグドロップは○
	この位置と大きさは｛15，15，454，446｝
	キャンバス1というキャンバスを作る
		その位置と大きさは｛0，26，438，360｝
		そのドッキング方向は「全体」
	ステータスバー1というステータスバーを作る
		その内容は「ステータスバー1」
		その移動順は1
		その位置と大きさは｛0，386，438，22｝
		ゲーム状態ラベルという状況ラベル部品をステータスバー1へ作る
			その文字配置は「左」
			その引き伸ばしは○
			その表示は○
			その大きさは｛423，17｝
			その幅は423
			その高さは17
			その相対位置は「右＋左＋下＋上」
	メニュー1というメニューを作る
		その内容は「メニュー1」
		その移動順は2
		その位置と大きさは｛0，0，438，26｝
		ゲームGメニューというメニュー項目をメニュー1へ追加する
			その表示は○
			その内容は「ゲーム(&G)」
			"はじめからSメニュー"というメニュー項目をメニュー1のゲームGメニューへ追加する
				その内容は「プレイヤ先手(&P)」
			ゲーム_コンピュータ先手項目というメニュー項目をメニュー1のゲームGメニューへ追加する
				その内容は「コンピュータ先手(&C)」
			スキップNメニューというメニュー項目をメニュー1のゲームGメニューへ追加する
				その内容は「スキップ(&N)」
			メニュー項目1という区切り線部品をメニュー1のゲームGメニューへ追加
				その大きさは｛187，6｝
				その幅は187
			終了Cメニューというメニュー項目をメニュー1のゲームGメニューへ追加する
				その内容は「終了(&X)」
		ヘルプHメニューというメニュー項目をメニュー1へ追加する
			その表示は○
			その内容は「ヘルプ(&H)」
			バージョン情報Aメニューというメニュー項目をメニュー1のヘルプHメニューへ追加する
				その内容は「バージョン情報(&A)」
	この設計スケール比率は｛96,96｝
終わり

//****************** ゲーム処理の手順 **********************//
ゲームを、開始する手順
	プレイヤを黒駒化する
	1からマス数まで横を増やしながら繰り返す
		1からマス数まで縦を増やしながら繰り返す
			マス（横）（縦）を初期化する
		そして
	そして
	マス（マス数/2）（マス数/2）を白駒化する
	マス（マス数/2+1）（マス数/2）を黒駒化する
	マス（マス数/2+1）（マス数/2+1）を白駒化する
	マス（マス数/2）（マス数/2+1）を黒駒化する
	キャンバス1を更新する

	配置を数える
	ゲーム中は○
終わり

マスを、初期化する手順
	1からマス数まで横を増やしながら繰り返す
		マス（横）は｛｝
		マス部品（横）は｛｝
		駒部品（横）は｛｝
		1からマス数まで縦を増やしながら繰り返す
			キャンバス1へ四角形を描いて枠とする
			マス部品（横）（縦）は、枠
				枠の位置と大きさは｛横×マスサイズ+10,縦×マスサイズ+10,マスサイズ,マスサイズ｝
				枠の線色は「青」
				枠の太さは1
				枠の背景色は、黄緑色
			キャンバス1へ円を描いて駒図形とする
				駒図形の位置と大きさは｛横×マスサイズ+10+マスサイズ*0.1,縦×マスサイズ+10+マスサイズ*0.1,マスサイズ*0.8,マスサイズ*0.8｝
				駒図形の線色は、黒
				駒図形の表示は×
			マス（横）（縦）は、駒情報（横、縦、駒図形）を作ったもの
			枠のタグは、マス（横）（縦）
			駒図形のタグは、マス（横）（縦）
		そして
	そして
	キャンバス1へ円を描いて駒図形とする
	駒図形の位置と大きさは｛5,5,マスサイズ*0.8,マスサイズ*0.8｝
	プレイヤは、駒情報（0、0、駒図形）を作ったもの
	ゲームを開始する
	キャンバス1を更新する
終わり

【座標】に、置けるかどうかを判定する手順
	【置けた】は×
	開始横は、座標（1）
	開始縦は、座標（2）
	横方向を-1から1まで増やしながら繰り返す
		縦方向を-1から1まで増やしながら繰り返す
			横方向が0かつ縦方向が0なら、繰り返しを続ける
			【横】は、開始横
			【縦】は、開始縦
			繰り返す
				横を横方向だけ増やす
				縦を縦方向だけ増やす
				横が0以下または、横がマス数より大きい、または、縦が0以下、または、縦がマス数より大きいなら、繰り返しから抜け出す
				マス（横）（縦）の色が0なら、繰り返しから抜け出す
				マス（横）（縦）の色がマス（開始横）（開始縦）の色なら
					横を横方向だけ減らす
					縦を縦方向だけ減らす
					横が開始横でないまたは縦が開始縦でないの間、繰り返す
						置けたは○
						マス（横）（縦）を裏返す
						横を横方向だけ減らす
						縦を縦方向だけ減らす
					そして
					繰り返しから抜け出す
				そして
			そして
		そして
	そして
	置けたを返す
終わり

【駒】を、置く手順
	プレイヤの色が1なら、駒を白駒化する。でなければ、駒を黒駒化する。
	結果は｛駒の横、駒の縦｝に置けるか
	結果が○なら、
		プレイヤを裏返す
		配置を数える
		キャンバス1を更新する
		判定する
		ゲーム中なら
			1秒待つ
			コンピュータの手を置く
		そして
	でなければ
		駒の色は0
		駒の図形の表示は×
	そして
終わり

コンピュータの手を、置く手順
	試行数は1
	繰り返す
		試行数が300なら、プレイヤを裏返す。繰り返しから抜け出す。
		仮横は（1からマス数までの乱数）
		仮縦は（1からマス数までの乱数）
		駒は、マス（仮横）（仮縦）
		駒の色が0なら
			プレイヤの色が1なら、駒を白駒化する。でなければ、駒を黒駒化する。
			｛仮横、仮縦｝に置けるなら
				プレイヤを裏返す
				配置を数える
				繰り返しから抜け出す
			でなければ
				駒の色は0
				駒の図形の表示は×
			そして
		そして
		試行数を増やす
	そして
	キャンバス1を更新する
	判定する
終わり

判定する手順
	白数が0または（残りが0かつ黒数が白数より大きい）なら
		「黒が勝ちました。」を情報アイコンで表示する
		ゲーム中は×
	他で黒数が0または（残りが0かつ白数が黒数より大きい）なら
		「白が勝ちました。」を情報アイコンで表示する
		ゲーム中は×
	他で残りが0かつ白数が黒数なら
		「引き分けです。」を情報アイコンで表示する
		ゲーム中は×
	そして
終わり

配置を、数える手順
	黒数は0
	白数は0
	残りは0
	1からマス数まで横を増やしながら繰り返す
		1からマス数まで縦を増やしながら繰り返す
			マス色は、マス（横）（縦）の色
			マス色について分岐
			0の場合
				残りを増やす
			1の場合
				白数を増やす
			-1の場合
				黒数を増やす
			そして
		そして
	そして
	ゲーム状態ラベルの内容は「白:[白数]　黒:[黒数]　残り:[残り]」
終わり

//****************** イベント手順 **********************//
キャンバス1のマウスのボタンが離された時の手順
	ゲーム中でないなら、抜け出す
	図形は、キャンバス1からイベントの座標を取得したもの
	図形が無でないかつ図形のタグが無でないなら
		駒は、図形のタグ
		駒の色が0なら
			駒を置く
		そして
	そして
終わり

はじめからSメニューがクリックされた時の手順
	ゲームを開始する
終わり

ゲーム_コンピュータ先手項目がクリックされた時の手順
	ゲームを開始する
	コンピュータの手を置く
終わり

スキップNメニューがクリックされた時の手順
	プレイヤを裏返す
	キャンバス1を更新する
	配置を数える
	1秒待つ
	コンピュータの手を置く
終わり

終了Cメニューがクリックされた時の手順
	閉じる
終わり

バージョン情報Aメニューがクリックされた時の手順
	「プロデルリバーシ」を情報アイコンで表示する
終わり
終わり

駒情報とは
	+色=0
	+縦
	+横
	+図形
	はじめ（横、縦、図形）の手順
		自分の横は、横
		自分の縦は、縦
		自分の図形は、図形
	終わり
	【自分】を、裏返す手順
		色が1なら
			黒駒化する
		でなければ
			白駒化する
		そして
	終わり
	【自分】を、初期化する手順
		色は0
		図形の背景色は、白
		図形の表示は×
	終わり
	【自分】を、白駒化する手順
		色は1
		図形の背景色は、白
		図形の表示は○
	終わり
	【自分】を、黒駒化する手順
		色は-1
		図形の背景色は、黒
		図形の表示は○
	終わり
終わり